10 !************************
20 ! PROGRAM PENTRU REZOLVAREA UNUI SISTEM NELINEAR DE ECUATII
30 !************************
40 !
50 CALL CLEAR
60 NVAR=2! Nr. variabilelor si ecuatiilor sistemului.
70 NSIG=5!Nr. cifrelor semnificative in variabile
80 PREC=10^(-NSIG)!si precizia la sfarsitul iteratiilor.
90 DIM A(10,10),B(10),X(10)!Pt. rez sist lin.
100 DIM XVECHI(10),XNOU(10)! Vectorii din procesul iter.
110 DIM YREF(10),YT(10)! Vectorii ecuatiilor nelineare.
115 DIM IPERM(10),X1(10),H(10,10)
120 REPS=1! Evaluam lungimea mantisei masinii.
130 REPS=REPS/2
140 IF REPS+1<>1 THEN 130
150 REPS=2*REPS
160 EPS=SQR(REPS)! Constanta folosita in eval. deriv. num.
170 !
180 !----- OBSERVATIE ------
190 !Daca lucrati in GWBASIC sau cu o masina cu exponentul maxim
200 !+/-38,EPS>256*SQR(REPS) ,  sau folositi simpla precizie.
210 !----------------------
220 IF PREC<REPS THEN PREC=REPS
230 XNOU(1)=11! Valorile initiale ale variabilelor.
240 XNOU(2)=12
250 !***********************
260 !Inceputul procesului iterativ
270 !***********************
280 FOR I=1 TO NVAR! Actualizarea variabilelor dupa iteratie.
290 XVECHI(I)=XNOU(I)
300 NEXT I
310 GOSUB 1320! Calculul ecuatiilor nelin. cu param actuali.
320 FOR I=1 TO NVAR!   Actualizarea valorilor de referinta
330 YREF(I)=YT(I)! pentru functiile din sistemul nelin.
340 NEXT I
350 FOR J=1 TO NVAR
360 PAS=ABS(X1(J))! Scala pasului in derivata numerica.
370 IF PAS<.1 THEN PAS=.1
380 PAS=PAS*EPS! Pasul in derivata numerica.
390 T=XVECHI(J)
400 XVECHI(J)=XVECHI(J)+PAS
410 GOSUB 1320! Functiile sistemului nelinear pt. deriv. num.
420 FOR I=1 TO NVAR! Sistemul linear utilizat in proc. iter.
430 A(I,J)=(YT(I)-YREF(I))/PAS
440 NEXT I
450 B(J)=YREF(J)! Termenii liberi in sistemul linear asoc.
460 XVECHI(J)=T! Refacerea vectorului de lucru.
470 NEXT J
480 GOSUB 720! Rezolvarea sistemului linear.
490 FOR I=1 TO NVAR! Corectarea valorilor variabilelor.
500 XNOU(I)=XVECHI(I)-X(I)
510 NEXT I
520 IQUIT=0! Incercarea criteriului de oprire.
530 FOR I=1 TO NVAR
540 IF ABS(XNOU(I)/XVECHI(I)-1)<PREC THEN IQUIT=IQUIT+1
550 NEXT I
560 IF IQUIT<>NVAR THEN 250
570 !
580 !=== S F A R S I T ===
590 !
600 CALL CLEAR
610 DISPLAY AT(6,1):USING "Ecuatiile cu # cifre semnificative : ":NSIG
620 FOR I=1 TO NVAR
630 DISPLAY AT(8+I,1):USING " y[#]=#.#####^^^^":I,XREF(I)
640 NEXT I
660 DISPLAY AT(12,1):"Radacinile sistemului sunt :"
680 FOR I=1 TO NVAR
690 DISPLAY AT(14+I,1):USING "x[#]=#.#####^^^^":I,XNOU(I)
700 NEXT I
710 END
720 !
730 !======================
740 ! SUBRUTINA PENTRU REZOLVAREA SISTEMULUI LINIAR
750 !=====================
760 !
770 FOR I=1 TO NVAR! Initializare
780 IPERM(I)=I! Initializam vectorul permutarilor liniilor
790 NEXT I
800 D=1! Initializam valoarea determinantului
810 FOR K=1 TO NVAR-1! Contorizarea eliminarilor
820 !
830 !NEXT K-CAUTAREA LINIEI PIVOT
840 !
850 L=K
860 I=K
870 I=I+1
880 IF ABS(A(I,K))>ABS(A(L,K))THEN L=I
890 IF I<NVAR-1 THEN 870
900 IF L=K THEN 1060
910 FOR J=K TO NVAR
920 T=A(K,J)
930 A(K,J)=A(L,J)
940 A(L,J)=T
950 NEXT J
960 T=B(K)
970 B(K)=B(L)
980 B(L)=T
990 D=-D! Prin perm. liniilor, det. isi schimba semnul.
1000 IT=IPERM(K)
1010 IPERM(K)=IPERM(L)
1020 IPERM(L)=IT! Contorizarea permutarilor
1030 !
1040 ! Triunghiularizarea metricii A
1050 !
1060 FOR I=K+1 TO NVAR
1070 T=A(I,K)/A(K,K)
1080 A(I,K)=T! Detaliile transformarii sunt salvate
1090 H(I,K)=0! sub diagonala, pentru inversare
1100 FOR J=K+1 TO NVAR
1110 A(I,J)=A(I,J)-T*A(K,J)
1120 H(I,J)=A(I,J)
1130 NEXT J
1140 B(I)=B(I)-T*B(K)
1150 NEXT I
1160 NEXT K
1170 FOR I=1 TO NVAR! Determinantul este produsul elem.diag.
1180 D=D*A(I,I)
1190 NEXT I
1200 !
1210 !-------  Construirea solutiilor sistemului liniar   ---------
1220 !
1230 X(NVAR)=B(NVAR)/A(NVAR,NVAR)
1240 FOR I=NVAR-1 TO 1 STEP-1
1250 S=0
1260 FOR J=I+1 TO NVAR
1270 S=S+A(I,J)*X(J)
1280 NEXT J
1290 X(I)=(B(I)-S)/A(I,I)
1300 NEXT I
1310 RETURN
1320 !
1330 !======================
1340 ! SUBRUTINA PENTRU CALCULUL FUNCTIILOR DIN
1350 ! SISTEMUL NELINEAR
1360 !======================
1370 !
1380 YT(1)=XVECHI(1)^3-3*XVECHI(1)*XVECHI(2)^2
1390 YT(1)=YT(1)-2*XVECHI(1)+2!Prima functie nelin.
1400 YT(2)=3*XVECHI(1)^2*XVECHI(2)-XVECHI(2)^3
1410 YT(2)=YT(2)-2*XVECHI(2)!A doua functie nelin.
1420 RETURN